%%HP: T(3)A(R)F(.);
\<< 
  "RC-FILTER" 
  { 
   { "R:" "WIDERSTAND_EINHEIT" 13 } 
   { "C:" "KAPAZIT\196T_EINHEIT" 13 } 
   { "F:" "FREQUENZ_EINHEIT" 13 } 
  } 
  { } 
  DUP DUP 
  INFORM
  WHILE 1. ==
    REPEAT 
       LIST\-> 
       DROP 
       \-> RE CE FE
       \<< 
          RE '0_\GW' CONVERT 
          CE '0_F' CONVERT 
          FE '0_Hz' CONVERT 
          UVAL \-> F
          \<< 
             UVAL \-> C
             \<< 
                UVAL \-> R
                \<<
                   CASE F 0 == THEN
                        2 \pi * R * C * INV 
                        'F' STO 
                        END 
                        R 0 == THEN
                        2 \pi * F * C * INV 
                        'R' STO
                        END 
                        C 0 == THEN
                        2 \pi * R * F * INV 
                        'C' STO
                        END
                   END 
                   R '0_\GW' \->UNIT 
                   RE RE - CONVERT 'RE' STO 
                   C '0_F' \->UNIT 
                   CE CE - CONVERT 'CE' STO 
                   F '0_Hz' \->UNIT 
                   FE FE - CONVERT 'FE' STO 
                   "RC-FILTER" 
                   { 
                    { "R:" "WIDERSTAND_EINHEIT" 13 } 
                    { "C:" "KAPAZIT\196T_EINHEIT" 13 } 
                    { "F:" "FREQUENZ_EINHEIT" 13 } 
                   } 
                   { } 
                   DUP 
                   RE CE FE 3. \->LIST 
                   INFORM
                \>>
             \>>
          \>>
       \>>
    END
\>>